Генерация комбинаций нескольких столбцов Excel с помощью VBA

Доступ к значениям в ячейках намного медленнее, чем к элементам массива. Поэтому имеет смысл предварительно считать все значения в память. Это можно сделать, например, так:

Function getAllSourceData(ByRef dTotalCombinations As Double) As Variant
Dim aRngs As Variant
Dim aRes As Variant
Dim i As Integer
    aRngs = Split(ALL_DATA_RANGES, ";")
    dTotalCombinations = 1
    ReDim aRes(LBound(aRngs) To UBound(aRngs))
    For i = LBound(aRngs) To UBound(aRngs)
        aRes(i) = getDataFromRange(aRngs(i))
        dTotalCombinations = dTotalCombinations * (UBound(aRes(i)) + 1)
    Next i
    getAllSourceData = aRes
End Function

Function getDataFromRange(ByVal sRange As String) As Variant
Dim oRange As Range
Dim oCell As Range
Dim aRes As Variant
Dim i As Long
    Set oRange = Range(sRange)
    ReDim aRes(0 To oRange.Cells.Count - 1)
    i = 0
    For Each oCell In oRange.Cells
        aRes(i) = oCell.Text
        i = i + 1
    Next oCell
    getDataFromRange = aRes
End Function

В результате будет создан массив, каждый из элементов которого - значения строк каждого из поддиапазонов (тоже массивы). Кроме того функция getAllSourceData() через параметр вернёт общее количество комбинаций, которые можно создать из собранных данных.

Получить одну случайную комбинацию из такой структуры можно так:

Function getNextString(aSourceData As Variant) As String
Const SEPARATOR As String = "-"
Dim i As Long
Dim sRes() As String
Dim Index As Long
    ReDim sRes(LBound(aSourceData) To UBound(aSourceData))
    For i = LBound(aSourceData) To UBound(aSourceData)
        Index = WorksheetFunction.RandBetween(LBound(aSourceData(i)), UBound(aSourceData(i)))
        sRes(i) = aSourceData(i)(Index)
    Next i
    getNextString = Join(sRes, SEPARATOR)
End Function

С этими тремя функциями можно собрать главную процедуру:

Sub ListPartCombinations()
Dim aData As Variant            
Dim oTargetCell As Range        
Dim dCount As Double            
Dim dictResults As Object       
Dim sRes As Variant             
    aData = getAllSourceData(dCount)
    If dCount < LAST_ROW Then
        Call MsgBox(("Исходных данных не хватит для генерации " & LAST_ROW & " значений" _
            & Chr(10) & "Воспользуйтесь алгоритмом ListAllCombinations()", _
            vbOKOnly + vbInformation, "Мало данных")
        Exit Sub
    End If
    Set dictResults = CreateObject("Scripting.Dictionary")
    While dictResults.Count <= LAST_ROW
        dictResults.Item(getNextString(aData)) = 0
    Wend
    Set oTargetCell = Range(FIRST_OUTPUT_CELL)
    For Each sRes In dictResults.keys
        oTargetCell.Value = sRes
        Set oTargetCell = oTargetCell.Offset(1, 0)
    Next sRes
End Sub

Для вывода накопленных значений в ячейки листа можно использовать Transpose(), но для очень больших наборов этот способ может не работать правильно.

Теперь достаточно добавить в заголовок модуля строки:

Option Explicit
Const ALL_DATA_RANGES = "A2:A8;C2:C170;E2:E178;G2:G35;I2:I18;K2:K15;M2:M15;O2:O10;X2:X16;Z2:Z3"
Const FIRST_OUTPUT_CELL = "AF2"
Const LAST_ROW As Long = 10000  

и программа готова к использованию.

Преимущества такого подхода:

• диапазонов с данными не обязательно должно быть ровно 10, их может быть больше или меньше
• диапазоны с данными могут быть не одной колонкой, а произвольной формы - строками или прямоугольниками

Недостаток - если возможных комбинаций не намного больше, чем ожидаемых результатов, то окончания работы программы можно ожидать довольно долго (постоянно генерируемые дубли отбрасываются словарём и компьютер вынужден многократно повторять бесполезные вычисления)